Arsse/dist/arch/PKGBUILD

pkgname="arsse"
pkgver=0.9.1.r10.7abdf05
pkgrel=1
epoch=
pkgdesc="RSS/Atom newsfeed synchronization server"
arch=("any")
url="https://thearsse.com/"
license=("MIT")
groups=()
depends=()
makedepends=("git" "php" "php-intl" "composer")
checkdepends=()
optdepends=("php-pgsql: PostgreSQL database support"
            "nginx: HTTP server"
            "apache: HTTP server")
provides=()
conflicts=()
replaces=()
backup=("etc/webapps/arsse/config.php" "etc/php/php-fpm.d/arsse.conf")
options=()
install=
changelog=
source=("git+file://$(dirname $(dirname $(pwd)))")
noextract=()
md5sums=("SKIP")

pkgver() {
    git describe --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
}

build() {
    cd "$srcdir/arsse"
    composer install
    ./robo manual
    composer install --no-dev -o -n --no-scripts
    php arsse.php conf save-defaults config.defaults.php
    rm -r vendor/bin
}

package() {
    depends=("php" "php-intl" "php-sqlite" "php-fpm")
    cd "$pkgdir"
    mkdir -p "usr/bin" "usr/share/webapps/arsse" "usr/share/doc/arsse" "usr/share/licenses/arsse" "usr/lib/systemd/system" "usr/lib/sysusers.d" "etc/php/php-fpm.d/" "etc/webapps/arsse" "etc/webapps/arsse/nginx"
    cd "$srcdir/arsse"
    cp dist/arch/arsse.sh "$pkgdir/usr/bin/arsse"
    cp -r lib locale sql vendor www CHANGELOG UPGRADING README.md arsse.php "$pkgdir/usr/share/webapps/arsse"
    cp -r manual/* "$pkgdir/usr/share/doc/arsse"
    cp LICENSE AUTHORS "$pkgdir/usr/share/licenses/arsse"
    cp dist/arch/*.service "$pkgdir/usr/lib/systemd/system"
    cp dist/arch/sysuser.conf "$pkgdir/usr/lib/sysusers.d/arsse.conf"
    cp dist/arch/php-fpm.conf "$pkgdir/etc/php/php-fpm.d/arsse.conf"
    cp dist/arch/config.php config.defaults.php "$pkgdir/etc/webapps/arsse"
    cp dist/arch/nginx/* "$pkgdir/etc/webapps/arsse/nginx"
    cd "$pkgdir"
    chmod -R a=rX *
    chmod a=rx usr/bin/arsse
    chmod u=r etc/webapps/arsse/*
    ln -sT "/etc/webapps/arsse/config.php" "usr/share/webapps/arsse/config.php"
}